home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / AMIGA / AMICUS / AMICUS01.ADF / Text / RAM disks < prev    next >
Internet Message Format  |  1985-12-04  |  4KB
  1. Path: puff!uwvax!seismo!lll-crg!qantel!ihnp4!nsc!pyramid!amiga!bruceb
  2. From: bruceb@amiga.UUCP (Bruce Barrett)
  3. Subject: Save This Execute File
  4. Date: 23 Nov 85 03:27:40 GMT
  5. Organization: Commodore-Amiga Inc., 983 University Ave #D, Los Gatos CA 95030
  6.  
  7.   Although I do not expect that most of you have more than 512k of memory
  8. or a hard disk yet I thought I'd share this with you for when you do.  It
  9. could even be useful if you customize your boot diskette to have only the
  10. "minimum daily requirement" of files on it.  (Some future mail will describe
  11. this.)
  12.  
  13.   I suggest you save this execute file for when you get a hard disk or
  14. another 512-1024K of RAM.  At that point you can use it to lessen your
  15. dependence on floppy diskettes. This could become part of your startup
  16. script.
  17.  
  18.   The execute file it fairly straight forward,... there are, however
  19. two strange sequences.
  20.  
  21. The first is the sequence:
  22.         ECHO "If you get a requester for a volume you do not \
  23.          have select 'CANCEL'."
  24.         IF NOT EXISTS <newdrive>
  25.            SKIP INFO
  26.         ENDIF
  27.  
  28. This should be thought of as a unit.  Its purpose is to deal with a 
  29. user who has mistyped his/her drive or volume name, yielding the
  30. "insert volume xxx" system requester.
  31.  
  32. The second sequence is:
  33.         failat 100           ; make sure the <newdrive> is volume, 
  34.                              ; drive or directory
  35.         cd <newdrive>
  36.         IF FAIL
  37.            SKIP INFO
  38.         ENDIF
  39.         failat 20
  40.  
  41. This confirms that you are about to assign to a directory.
  42.  
  43.   As always, ENJOY!
  44.  
  45.         Bruce Barrett
  46.  
  47.  
  48. . --------------- Cut Here ----------------------, do not keep this line.
  49.  
  50. .key newdrive
  51. . --- Move the system assignments to a new drive.        Version 1.5
  52. . --- This may be a RAM: disk, Hard Disk, or Floppy.     22-Nov-85
  53. . --- If the needed directories are not present they will be copied from
  54. . --- the current.
  55.  
  56. IF "<newdrive>" EQ ""
  57.    SKIP INFO
  58. ENDIF
  59.  
  60. failat 100           ; make sure the <newdrive> is volume, drive or directory
  61. cd <newdrive>
  62. IF FAIL
  63.    SKIP INFO
  64. ENDIF
  65. failat 20
  66.  
  67. ECHO "I am about to move the logical device assignments from their current"
  68. ECHO "locations to <newdrive>."
  69. ECHO "If you get a request for a volume you do not have select 'CANCEL'."
  70.  
  71. IF NOT EXISTS <newdrive>
  72.    SKIP INFO
  73. ENDIF
  74.  
  75. ;  Test for all "real important" subdirectories.
  76.  
  77. IF NOT EXISTS <newdrive>C
  78.    ECHO "Subdirectory 'C' missing on <newdrive>.  The current 'C:' directory"
  79.    ECHO "will be used to create it."
  80.    makedir <newdrive>C
  81.    copy c: to <newdrive>C all quiet
  82. ENDIF
  83. IF NOT EXISTS <newdrive>L
  84.    ECHO "Subdirectory 'L' missing on <newdrive>.  The current 'L:' directory"
  85.    ECHO "will be used to create it."
  86.    makedir <newdrive>L
  87.    copy L: to <newdrive>L all quiet
  88. ENDIF
  89. IF NOT EXISTS <newdrive>LIBS
  90.    ECHO "Subdirectory 'LIBS' missing on <newdrive>.  The current 'LIBS:' directory"
  91.    ECHO "will be used to create it."
  92.    makedir <newdrive>LIBS
  93.    copy LIBS: to <newdrive>LIBS all quiet
  94. ENDIF
  95. IF NOT EXISTS <newdrive>DEVS
  96.    ECHO "Subdirectory 'DEVS' missing on <newdrive>.  The current 'DEVS:' directory"
  97.    ECHO "will be used to create it."
  98.    makedir <newdrive>DEVS
  99.    copy DEVS: to <newdrive>DEVS all quiet
  100. ENDIF
  101. IF NOT EXISTS <newdrive>FONTS
  102.    ECHO "Subdirectory 'FONTS' missing on <newdrive>.  The current 'FONTS:' directory"
  103.    ECHO "will be used to create it."
  104.    makedir <newdrive>FONTS
  105.    copy FONTS: to <newdrive>FONTS all quiet
  106. ENDIF
  107. IF NOT EXISTS <newdrive>S
  108.    ECHO "Subdirectory 'S' missing on <newdrive>.  The current 'S:' directory"
  109.    ECHO "will be used to create it."
  110.    makedir <newdrive>S
  111.    copy S: to <newdrive>S all quiet
  112. ENDIF
  113. IF NOT EXISTS <newdrive>T
  114.    makedir <newdrive>T
  115. ENDIF
  116.  
  117. ;  Do all the assignments.
  118.  
  119. assign sys: <newdrive>
  120. assign c:   sys:c
  121. assign s:   sys:s
  122. assign l:   sys:l
  123. assign libs: sys:libs
  124. assign fonts: sys:fonts
  125. assign devs:  sys:devs
  126. ECHO "Assignments complete.  Ready to use <newdrive>."
  127. SKIP EXIT
  128.  
  129. LAB INFO
  130. echo "You must specify  DRIVE: or VOLUMENAME:."
  131. Echo "Examples:"
  132. echo "   execute move.sys df1:            (external floppy)."
  133. echo "   execute move.sys dh0:            (hard disk)."
  134. echo "   execute move.sys RAM:            (RAM: disk)."
  135. echo "Don't forget to include the colon (*":*")!"
  136. LAB EXIT
  137.